All I don't know » ActionScript http://blog.derraab.com About Flash™, Flex™, software development and my computer. And JavaScript. Sat, 26 Nov 2011 18:31:36 +0000 en hourly 1 http://wordpress.org/?v=3.3.1 Removing comments in CSS, HTML and ECMAScript (JavaScript) http://blog.derraab.com/2011/11/26/removing-comments-in-css-html-and-ecmascript-javascript/ http://blog.derraab.com/2011/11/26/removing-comments-in-css-html-and-ecmascript-javascript/#comments Sat, 26 Nov 2011 18:31:36 +0000 derRaab http://blog.derraab.com/?p=767 Continue reading →]]> While working on an Adobe AIR based source code editor I was looking for an easy way to remove comments from different kind of source codes. What first seemed like an easy regular expression turned out to be much more complex because comment pre- and suffixes can also occur in string literals or regular expressions and our old friend Internet Explorer allows HTML conditional comments and JavaScript conditional compilation. Great.

First I had a look at YUICompressors source code and Google Page Speed but then I decided to port a script for removing JavaScript comments created by James Padolsey.

I just improved the recognition for regular expressions a little and since this code should work with all ECMAScript based source codes I named my class ECMAScriptParser instead of JavaScriptParser:

package de.superclass.parser
{
    /**
     * @author Markus Raab (superclass.de | blog.derRaab.com)
     */
    public class ECMAScriptParser
    {
        /**
         * Removes inline and block comments from an ECMAScript source string. 
         * 
         * This is a port of James Padolsey     with an slightly improved RegExp recognition.
         * @see: http://james.padolsey.com/javascript/removing-comments-in-javascript
         * 
         * @param ecmaScript        ECMAScript source string
         * @param removeCondComp    Optional (default=false) - Whether to remove Internet Explorers JavasScript conditional compilation comments or not.   
         * @return                    ECMAScript source string without comments
         */
        public static function removeComments( ecmaScript : String, removeCondComp : Boolean = false ) : String
        {
            var modeSingleQuote        : Boolean = false;
            var modeDoubleQuote        : Boolean = false;
            var modeRegExp            : Boolean = false;
            var modeBlockComment    : Boolean = false;
            var modeLineComment        : Boolean = false;
            var modeCondComp        : Boolean = false; 
 
            var vector : Vector.<String> = Vector.<String>( ( '__' + ecmaScript + '__' ).split( '' ) );
                vector.fixed = true;
 
            var c : int = vector.length;
 
            for ( var i : int = 0; i < c; i++ )
            {
                var string : String = vector[ i ];
 
                if ( modeRegExp )
                {
                    if ( string === '/' && vector[ i - 1 ] !== '\\' )
                    {
                        modeRegExp = false;
                    }
                    continue;
                }
 
                if ( modeSingleQuote )
                {
                    if ( string === "'" && vector[ i - 1 ] !== '\\' )
                    {
                        modeSingleQuote = false;
                    }
                    continue;
                }
 
                if ( modeDoubleQuote )
                {
                    if ( string === '"' && vector[ i - 1 ] !== '\\' )
                    {
                        modeDoubleQuote = false;
                    }
                    continue;
                }
 
                if ( modeBlockComment )
                {
                    if ( string === '*' && vector[ i + 1 ] === '/' )
                    {
                        vector[ i + 1 ] = '';
                        modeBlockComment = false;
                    }
                    vector[ i ] = '';
                    continue;
                }
 
                if ( modeLineComment)
                {
                    string = vector[ i + 1 ];
                    if ( string === '\n' || string === '\r' )
                    {
                        modeLineComment = false;
                    }
                    vector[ i ] = '';
                    continue;
                }
 
                if ( modeCondComp )
                {
                    if ( vector[ i - 2 ] === '@' && vector[ i - 1 ] === '*' && string === '/' )
                    {
                        modeCondComp = false;
                    }
                    continue;
                }
 
                if ( string === '"' )
                {
                    modeDoubleQuote = true;
                    continue;
                }
 
                if ( string === "'" )
                {
                    modeSingleQuote = true;
                    continue;
                }
 
                if ( string === '/' )
                {
                    if ( ! removeCondComp && vector[ i + 1 ] === '*' && vector[ i + 2 ] === '@' )
                    {
                        modeCondComp = true;
                        continue;
                    }
 
                    if ( vector[ i + 1 ] === '*' )
                    {
                        vector[ i ] = '';
 
                        modeBlockComment = true;
                        continue;
                    }
 
                    if ( vector[ i + 1 ] === '/' )
                    {
                        vector[ i ] = '';
                        modeLineComment = true;
                        continue;
                    }
 
                    for ( var k : int = i - 1; true; k-- )
                    {
                        string = vector[ k ];
                        if ( string !== ' ' )
                        {
                            if ( string === '=' )
                            {
                                modeRegExp = true;
                            }
                            break;
                        }
                    }
                }
            }
            return vector.join( '' ).slice( 2, -2 );
        }
    }
}

Allright – CSS doesn’t allow inline or conditional comments so I removed this script functionality and created a CSSParser class:

package de.superclass.parser
{
    /**
     * @author Markus Raab (superclass.de | blog.derRaab.com)
     */
    public class CSSParser
    {
        /**
         * Removes comments from a CSS string. 
         * 
         * This is a shrinked port of James Padolseys script.
         * @see: http://james.padolsey.com/javascript/removing-comments-in-javascript
         * 
         * @param css                CSS string
         * @return                    CSS string without comments
         */
        public static function removeComments( css : String) : String
        {
            var modeSingleQuote        : Boolean = false;
            var modeDoubleQuote        : Boolean = false;
            var modeBlockComment    : Boolean = false;
 
            var vector : Vector.<String> = Vector.<String>( ( '__' + css + '__' ).split( '' ) );
                vector.fixed = true;
 
            var c : int = vector.length;
 
            for ( var i : int = 0; i < c; i++ )
            {
                var string : String = vector[ i ];
 
                if ( modeSingleQuote )
                {
                    if ( string === "'" && vector[ i - 1 ] !== '\\' )
                    {
                        modeSingleQuote = false;
                    }
                    continue;
                }
 
                if ( modeDoubleQuote )
                {
                    if ( string === '"' && vector[ i - 1 ] !== '\\' )
                    {
                        modeDoubleQuote = false;
                    }
                    continue;
                }
 
                if ( modeBlockComment )
                {
                    if ( string === '*' && vector[ i + 1 ] === '/' )
                    {
                        vector[ i + 1 ] = '';
                        modeBlockComment = false;
                    }
                    vector[ i ] = '';
                    continue;
                }
 
                if ( string === '"' )
                {
                    modeDoubleQuote = true;
                    continue;
                }
 
                if ( string === "'" )
                {
                    modeSingleQuote = true;
                    continue;
                }
 
                if ( string === '/' )
                {
                    if ( vector[ i + 1 ] === '*' )
                    {
                        vector[ i ] = '';
 
                        modeBlockComment = true;
                        continue;
                    }
                }
            }
            return vector.join( '' ).slice( 2, -2 );
        }
    }
}

Good. Lastly I extended the code to remove all comments within HTML source code, which can also contain JavaScript and of course CSS. This is the HTMLParser:

package de.superclass.parser
{
    /**
     * @author Markus Raab (superclass.de | blog.derRaab.com)
     */
    public class HTMLParser
    {
        /**
         * Removes all HTML, CSS and ECMAScript comments from a HTML string.
         * 
         * This is an extended port of James Padolseys script with an improved RegExp recognition.
         * @see: http://james.padolsey.com/javascript/removing-comments-in-javascript
         * 
         * @param html                        HTML string
         * @param removeHTMLCondComment        Optional (default=false) - Whether to remove Internet Explorers HTML conditional comments or not.
         * @param removeJSCondComp            Optional (default=false) - Whether to remove Internet Explorers JavasScript conditional compilation comments or not.
         * @return                            HTML string without comments
         */
        public static function removeComments( html : String, removeHTMLCondComment : Boolean = false, removeJSCondComp : Boolean = false ) : String
        {
            var modeSingleQuote        : Boolean = false;
            var modeDoubleQuote        : Boolean = false;
            var modeRegExp            : Boolean = false;
            var modeBlockComment    : Boolean = false;
            var modeLineComment        : Boolean = false;
 
            var modeJSCondComp        : Boolean = false;
 
            var modeHTMLComment        : Boolean = false;
            var modeHTMLCondComment    : Boolean = false;
 
            var vector : Vector.<String> = Vector.<String>( ( '__' + html + '__' ).split( '' ) );
                vector.fixed = true;
 
            var c : int = vector.length;
 
            for ( var i : int = 0; i < c; i++ )
            {
                var string : String = vector[ i ];
 
                if ( modeRegExp )
                {
                    if ( string === '/' && vector[ i - 1 ] !== '\\' )
                    {
                        modeRegExp = false;
                    }
                    continue;
                }
 
                if ( modeSingleQuote )
                {
                    if ( string === "'" && vector[ i - 1 ] !== '\\' )
                    {
                        modeSingleQuote = false;
                    }
                    continue;
                }
 
                if ( modeDoubleQuote )
                {
                    if ( string === '"' && vector[ i - 1 ] !== '\\')
                    {
                        modeDoubleQuote = false;
                    }
                    continue;
                }
 
                if ( modeBlockComment )
                {
                    if ( string === '*' && vector[ i + 1 ] === '/')
                    {
                        vector[ i + 1 ] = '';
                        modeBlockComment = false;
                    }
                    vector[ i ] = '';
                    continue;
                }
 
                if ( modeLineComment)
                {
                    string = vector[ i + 1 ];
                    if ( string === '\n' || string === '\r' )
                    {
                        modeLineComment = false;
                    }
                    vector[ i ] = '';
                    continue;
                }
 
                if ( modeJSCondComp )
                {
                    if ( vector[ i - 2 ] === '@' && vector[ i - 1 ] === '*' && string === '/' )
                    {
                        modeJSCondComp = false;
                    }
                    continue;
                }
 
                if ( modeHTMLComment )
                {
                    // --> 
                    if ( string === '-' && vector[ i + 1 ] === '-' && vector[ i + 2 ] === '>' )
                    {
                        vector[ i + 1 ] = '';
                        vector[ i + 2 ] = '';
 
                        modeHTMLComment = false;
                    }
                    vector[ i ] = '';
                    continue;
                }
 
                if ( modeHTMLCondComment )
                {
                    if ( string === 'i' && vector[ i + 1 ] === 'f' && vector[ i + 2 ] === ']' && vector[ i + 3 ] === '-' && vector[ i + 4 ] === '-' && vector[ i + 5 ] === '>' ) // if]--> 
                    {
                        modeHTMLCondComment = false;
                        i += 5;
                    }
                    continue;
                }
 
                if ( string === '<' && vector[ i + 1 ] === '!' && vector[ i + 2 ] === '-' && vector[ i + 3 ] === '-' ) // <!--
                {
                    if ( ! removeHTMLCondComment && vector[ i + 4 ] === '[' && vector[ i + 5 ] === 'i' && vector[ i + 6 ] === 'f' ) // <!--[if
                    {
                        modeHTMLCondComment = true;
                    }
                    else
                    {
                        vector[ i ] = '';
                        modeHTMLComment = true;
                    }
                }
 
                if ( string === '"' )
                {
                    modeDoubleQuote = true;
                    continue;
                }
 
                if ( string === "'" )
                {
                    modeSingleQuote = true;
                    continue;
                }
 
                if ( string === '/' )
                {
                    if ( ! removeJSCondComp && vector[ i + 1 ] === '*' && vector[ i + 2 ] === '@' )
                    {
                        modeJSCondComp = true;
                        continue;
                    }
 
                    if ( vector[ i + 1 ] === '*' )
                    {
                        vector[ i ] = '';
 
                        modeBlockComment = true;
                        continue;
                    }
 
                    if ( vector[ i + 1 ] === '/' )
                    {
                        vector[ i ] = '';
                        modeLineComment = true;
                        continue;
                    }
 
                    for ( var k : int = i - 1; true; k-- )
                    {
                        string = vector[ k ];
                        if ( string !== ' ' )
                        {
                            if ( string === '=' )
                            {
                                modeRegExp = true;
                            }
                            break;
                        }
                    }
                }
            }
            return vector.join( '' ).slice( 2, -2 );
        }
    }
}

Let me know if I made a mistake but it seems to work quite well. Or do you know a good library that already does this kind of optimizations?

Well, that’s it for now. Have fun coding!

]]> http://blog.derraab.com/2011/11/26/removing-comments-in-css-html-and-ecmascript-javascript/feed/ 0 Linked List Performance Test using Getter or Interface http://blog.derraab.com/2011/04/21/linked-list-performance-test-using-getter-or-interface/ http://blog.derraab.com/2011/04/21/linked-list-performance-test-using-getter-or-interface/#comments Thu, 21 Apr 2011 13:30:52 +0000 derRaab http://blog.derraab.com/?p=596 Continue reading →]]> Another test regarding linked lists. Since I heavily use interfaces within the frameworks I’m working on I tried to define interfaces for my linked list items. I would love to use an abstract interface but with the full linked list speed. Seems not possible. If you create an interface you need to use at least one getter function which kills performance.

I compared execution time using this code:

package
{
    import flash.utils.getTimer;
    import flash.events.Event;
    import flash.display.Sprite;
 
    public final class LinkedListPerformanceCheck extends Sprite
    {
        private var _firstItemWithPublicVar : ItemWithPublicVar;
        private var _firstFinalItemWithPublicVar : FinalItemWithPublicVar;
        private var _firstItemWithGetter : ItemWithGetter;
        private var _firstFinalItemWithGetter : FinalItemWithGetter;
        private var _firstIItemWithGetter : IItemWithGetter;
        private var _firstIFinalItemWithGetter : IFinalItemWithGetter;
 
        private var _c : int;
        private var _i : int;
 
        public function LinkedListPerformanceCheck()
        {
            loaderInfo.addEventListener( Event.COMPLETE, run );
        }
 
        private function run( event : Event ) : void
        {
            _c = 5000000;
            _i = 0;
            addEventListener( Event.ENTER_FRAME, onEnterFrame );
        }
 
        private function onEnterFrame( event : Event ) : void
        {
            switch( _i++ )
            {
                case 0 : createItemWithPublicVarTest(); break;
                case 1 : createFinalItemWithPublicVarTest(); break;
                case 2 : createItemWithGetterTest(); break;
                case 3 : createFinalItemWithGetterTest(); break;
                case 4 : createImplementedIItemWithGetterTest(); break;
                case 5 : createImplementedIFinalItemWithGetterTest(); break;
                case 6 : break; // wait
                case 7 : break; // wait
                case 8 : break; // wait
                case 9 : break; // wait
                case 10 : runItemWithPublicVarTest(); break;
                case 11 : runFinalItemWithPublicVarTest(); break;
                case 12 : runItemWithGetterTest(); break;
                case 13 : runFinalItemWithGetterTest(); break;
                case 14 : runImplementedIItemWithGetterTest(); break;
                case 15 : runImplementedIFinalItemWithGetterTest(); break;
                case 16 : runItemWithPublicVarTest(); break; // again - just to make sure...
                case 17 : runFinalItemWithPublicVarTest(); break; // again - just to make sure...
                default: removeEventListener( Event.ENTER_FRAME, onEnterFrame );
            }
        }
 
        private function createItemWithPublicVarTest() : void
        {
            var item : ItemWithPublicVar = _firstItemWithPublicVar = new ItemWithPublicVar();
            for ( var i : int = 0; i < _c; i++ ) { item = item.next = new ItemWithPublicVar(); }
        }
 
        private function runItemWithPublicVarTest() : void
        {
            var item : ItemWithPublicVar = _firstItemWithPublicVar;
            var startTime : int = getTimer();
            while( item ){ item = item.next; }
            var duration : int = getTimer() - startTime;
            trace("LinkedListPerformanceCheck.runItemWithPublicVarTest( " +duration + " )");
        }
 
        private function createFinalItemWithPublicVarTest() : void
        {
            var item : FinalItemWithPublicVar = _firstFinalItemWithPublicVar = new FinalItemWithPublicVar();
            for ( var i : int = 0; i < _c; i++ ) { item = item.next = new FinalItemWithPublicVar(); }
        }
 
        private function runFinalItemWithPublicVarTest() : void
        {
            var item : FinalItemWithPublicVar = _firstFinalItemWithPublicVar;
            var startTime : int = getTimer();
            while( item ){ item = item.next; }
            var duration : int = getTimer() - startTime;
            trace("LinkedListPerformanceCheck.runFinalItemWithPublicVarTest( " +duration + " )");
        }
 
        private function createItemWithGetterTest() : void
        {
            var item : ItemWithGetter = _firstItemWithGetter = new ItemWithGetter();
            for ( var i : int = 0; i < _c; i++ ) { item = item.next = new ItemWithGetter(); }
        }
 
        private function runItemWithGetterTest() : void
        {
            var item : ItemWithGetter = _firstItemWithGetter;
            var startTime : int = getTimer();
            while( item ){ item = item.next; }
            var duration : int = getTimer() - startTime;
            trace("LinkedListPerformanceCheck.runItemWithGetterTest( " +duration + " )");
        }
 
        private function createFinalItemWithGetterTest() : void
        {
            var item : FinalItemWithGetter = _firstFinalItemWithGetter = new FinalItemWithGetter();
            for ( var i : int = 0; i < _c; i++ ) { item = item.next = new FinalItemWithGetter(); }
        }
 
        private function runFinalItemWithGetterTest() : void
        {
            var item : FinalItemWithGetter = _firstFinalItemWithGetter;
            var startTime : int = getTimer();
            while( item ){ item = item.next; }
            var duration : int = getTimer() - startTime;
            trace("LinkedListPerformanceCheck.runFinalItemWithGetterTest( " +duration + " )");
        }
 
        private function createImplementedIItemWithGetterTest() : void
        {
            var item : IItemWithGetter = _firstIItemWithGetter = new ImplementedIItemWithGetter();
            for ( var i : int = 0; i < _c; i++ ) { item = item.next = new ImplementedIItemWithGetter(); }
        }
 
        private function runImplementedIItemWithGetterTest() : void
        {
            var item : IItemWithGetter = _firstIItemWithGetter;
            var startTime : int = getTimer();
            while( item ){ item = item.next; }
            var duration : int = getTimer() - startTime;
            trace("LinkedListPerformanceCheck.runImplementedIItemWithGetterTest( " +duration + " )");
        }
 
        private function createImplementedIFinalItemWithGetterTest() : void
        {
            var item : IFinalItemWithGetter = _firstIFinalItemWithGetter = new ImplementedIFinalItemWithGetter();
            for ( var i : int = 0; i < _c; i++ ) { item = item.next = new ImplementedIFinalItemWithGetter(); }
        }
 
        private function runImplementedIFinalItemWithGetterTest() : void
        {
            var item : IFinalItemWithGetter = _firstIFinalItemWithGetter;
            var startTime : int = getTimer();
            while( item ){ item = item.next; }
            var duration : int = getTimer() - startTime;
            trace("LinkedListPerformanceCheck.runImplementedIFinalItemWithGetterTest( " +duration + " )");
        }
    }
}
 
class ItemWithPublicVar { public var next : ItemWithPublicVar; }
 
final class FinalItemWithPublicVar { public var next : FinalItemWithPublicVar; }
 
class ItemWithGetter
{
    private var _next : ItemWithGetter;
    public function get next() : ItemWithGetter { return _next; }
    public function set next( value : ItemWithGetter ) : void { _next = value; }
}
 
final class FinalItemWithGetter
{
    private var _next : FinalItemWithGetter;
    public function get next() : FinalItemWithGetter { return _next; }
    public function set next( value : FinalItemWithGetter ) : void { _next = value; }
}
 
interface IItemWithGetter
{
    function get next() : IItemWithGetter;
    function set next( value : IItemWithGetter ) : void;
}
 
class ImplementedIItemWithGetter implements IItemWithGetter
{
    private var _next : IItemWithGetter;
    public function get next() : IItemWithGetter { return _next; }
    public function set next( value : IItemWithGetter ) : void { _next = value; }
}
 
interface IFinalItemWithGetter
{
    function get next() : IFinalItemWithGetter;
    function set next( value : IFinalItemWithGetter ) : void;
}
 
final class ImplementedIFinalItemWithGetter implements IFinalItemWithGetter
{
    private var _next : IFinalItemWithGetter;
    public function get next() : IFinalItemWithGetter { return _next; }
    public function set next( value : IFinalItemWithGetter ) : void { _next = value; }
}

Result:

LinkedListPerformanceCheck.runItemWithPublicVarTest( 86 )
LinkedListPerformanceCheck.runFinalItemWithPublicVarTest( 88 )
LinkedListPerformanceCheck.runItemWithGetterTest( 1247 )
LinkedListPerformanceCheck.runFinalItemWithGetterTest( 1148 )
LinkedListPerformanceCheck.runImplementedIItemWithGetterTest( 1161 )
LinkedListPerformanceCheck.runImplementedIFinalItemWithGetterTest( 1160 )
LinkedListPerformanceCheck.runItemWithPublicVarTest( 64 )
LinkedListPerformanceCheck.runFinalItemWithPublicVarTest( 62 )

Using public variables instead of getter functions is much faster. To make sure memory allocation doesn’t kill performance I repeated the public variables test at the end. Even faster.

Is there a way to define Interfaces for public variables?

]]> http://blog.derraab.com/2011/04/21/linked-list-performance-test-using-getter-or-interface/feed/ 0 FFK11 – beyond tellerrand notes http://blog.derraab.com/2011/04/08/ffk11-beyond-tellerrand-notes/ http://blog.derraab.com/2011/04/08/ffk11-beyond-tellerrand-notes/#comments Fri, 08 Apr 2011 22:03:46 +0000 derRaab http://blog.derraab.com/?p=578 Continue reading →]]> I’m still not sure if “beyond tellerrand” is a subtitle or will become the new brand for the one and only Flashforum conference here in germany. Sascha Wolter and Marc Thiele did a great job as always and even I never went to another conference, FFK seems still to be a special one. Again I was lucky listening to some really cool stuff.

Interestingly most of my last year notes are still up to date, which doesn’t help if you don’t keep them in mind. So I think it’s a good idea to read my own notes from time to time. ;)

That’s what I became aware of this time:

AIR 2.6

  • Lee Brimelow mentioned AIR 2.6 on iOS is faster than on Android! Yeah.
  • Adobe is working hard on increasing performance near to native code.
  • Installing a runtime seems to be annoying for Android users, so Adobe is thinking about compiling for Android like for iOS. Which might bring some extra performance as well.
  • I asked Lee Brimelow about AIR on Windows Phone 7 and he said something like “Adobe is currently not working on that and it would be a lot of work”. Well, of course Microsoft is not interested having AIR on their system, but it would be a really important platform for all of us. So in my opinion Adobe at least has a small team checking out what’s possible. What do you think about Windows Phone 7 and AIR support?

Flex Builder 4.5

  • You can get Flex SDK 4.5 already, but there’s also a way to join the private pre-release program to get early access to Flex Builder 4.5. Just visit http://www.surveymonkey.com/s/flexprerelease. They are working on some useful stuff and it might be a good idea to test some of the new features.
  • Deepa Supramaniam mentioned spark MXML skins have performance issues on mobile devices. That’s why they created pure ActionScript spark skins for mobile applications. Hopefully, within the private beta Flex SDKs, we’ll find some great improvements: http://www.riagora.com/2011/03/preview-of-flex-on-ios/.

NUI

  • Wolfgang Henseler (Talk I missed at FFK10) opened my mind according NUI.
  • Don’t think of apps on mobile devices but of services allowing you reaching your goal faster than a website.
  • Think about providing services, combining them, rethinking them.
  • Use less design and let objects provide their functionalities (e.g. tap on image to get some options).
  • My brain is very busy with that NUI thing. E. g. he mentioned the Siri iPhone app. It’s not about how it looks like (not so cool) but how it works! Combining lots of possibilities with a really easy interface (speech) . He was also talking about “in body technology” (sensors and stuff like that.) and http://www.tedmed.com/
  • After Dennis Ippels Kinect (OpenKinect / http://www.primesense.com/) introduction I finally know something about the magic behind this device as well.

Molehill

Additional useful links:

]]> http://blog.derraab.com/2011/04/08/ffk11-beyond-tellerrand-notes/feed/ 3 SWF meta tag http://blog.derraab.com/2011/04/04/swf-meta-tag/ http://blog.derraab.com/2011/04/04/swf-meta-tag/#comments Mon, 04 Apr 2011 15:00:39 +0000 derRaab http://blog.derraab.com/?p=549 Continue reading →]]> I’m always searching for it so here is a useful blogpost.

As the latest FDT version ( Beta 4 ) does not set compiler arguments concerning SWF-size, framerate etc. by default I started using SWF-Metatags to specify these settings.

I’m talking of these things:

[SWF(width="910", height="610", backgroundColor="#FFFFFF", frameRate="40")]

Just set this tag above your class opening in the one you’re going to compile. Here is a complete list of (useful) arguments you can pass in:

width
widthPercent
height
heightPercent
scriptTimeLimit
frameRate
backgroundColor

So basically this is the fastest way to set up common compile-arguments to your project. By the way there is no Flex-Framework required – these tags also work in pure AS3 projects.

]]> http://blog.derraab.com/2011/04/04/swf-meta-tag/feed/ 0 Date.time vs. Date.setTime() getTime() performance http://blog.derraab.com/2011/03/24/date-time-vs-date-settime-gettime-performance/ http://blog.derraab.com/2011/03/24/date-time-vs-date-settime-gettime-performance/#comments Thu, 24 Mar 2011 14:14:17 +0000 derRaab http://blog.derraab.com/?p=540 Continue reading →]]> Using Date.setTime() and Date.getTime() is faster than Date.time.

My quick speed test to determine the fastest way to get and set time values on Date objects:

var date : Date = new Date();
var max : Number = date.time;
 
var start : int;
var end : int;
var time : Number;
var times : Vector.<Number> = new Vector.<Number>(); 
 
var c : int = 1000000;
for ( var i : int = 0; i < c; i++ ) { times.push( Math.round( max * Math.random() ) ); }
 
start = getTimer();
for ( i = 0; i < c; i++ ) { date.time = times[ i ]; };
end = getTimer();
trace( "date.time = times[ i ];", end - start );
 
start = getTimer();
for ( i = 0; i < c; i++ ) { date.setTime( times[ i ] ); };
end = getTimer();
trace( "date.setTime( times[ i ] );", end - start );
 
start = getTimer();
for ( i = 0; i < c; i++ ) { time = date.time; };
end = getTimer();
trace( "time = date.time;", end - start );
 
start = getTimer();
for ( i = 0; i < c; i++ ) { time = date.getTime(); };
end = getTimer();
trace( "time = date.getTime();", end - start );
 
// Result:
//
// date.time = times[ i ];        381
// date.setTime( times[ i ] );    270
// time = date.time;            184
// time = date.getTime();        65
]]> http://blog.derraab.com/2011/03/24/date-time-vs-date-settime-gettime-performance/feed/ 4 Linked List Performance Test http://blog.derraab.com/2010/09/22/linked-list-performance-test/ http://blog.derraab.com/2010/09/22/linked-list-performance-test/#comments Wed, 22 Sep 2010 17:11:56 +0000 derRaab http://blog.derraab.com/?p=410 Continue reading →]]> I was thinking about not creating linked lists for every data type I use but using one abstract data structure containing my specific data types.

So I wrote this short performance check:

package de.superclass 
{
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.events.TimerEvent;
    import flash.utils.Timer;
    import flash.utils.getTimer;
 
    public final class LinkedListTest extends Sprite 
    {
        private var _abstractItemLinkedList : AbstractItem;
        private var _dataItemLinkedList : DataItem;
        private var _vector : Vector.<DataItem>;
 
        public function LinkedListTest()
        {
            loaderInfo.addEventListener( Event.COMPLETE, onLoaderInfoComplete );
        }
 
        private function onLoaderInfoComplete( event : Event ) : void 
        {
            createData( );
 
            var timer : Timer = new Timer( 3000, 1 );
                timer.addEventListener( TimerEvent.TIMER_COMPLETE, onTimerComplete );
                timer.start();
        }
 
        private function onTimerComplete(event : TimerEvent) : void 
        {
            runTest( );
        }
 
        private function createData() : void 
        {
            var vector : Vector.<DataItem> = _vector = new Vector.<DataItem>();
            for ( var i : int = 0; i < 5000000; i++ )
            {
                var dataItem : DataItem = new DataItem();
                    dataItem.index = i;
 
                vector.push( dataItem );
 
                var abstractItem : AbstractItem = new AbstractItem();
                    abstractItem.data = dataItem;
 
                if ( i == 0 )
                {
                    _dataItemLinkedList = dataItem;
                    _abstractItemLinkedList = abstractItem;
                }
                else
                {
                    previousDataItem.next = dataItem;
                    previousAbstractItem.next = abstractItem;
                }
 
                var previousDataItem : DataItem = dataItem;
                var previousAbstractItem : AbstractItem = abstractItem;
            }
        }
 
        private function runTest() : void 
        {
            var dataItem : DataItem;
            var startTime : int;
 
            var vector : Vector.<DataItem> = _vector;
            var c : int = vector.length;
 
            startTime = getTimer();
            for ( var i : int = 0; i < c; i++ )
            {
                dataItem = vector[ i ];
                dataItem.index = dataItem.index;
            }
 
            var durationVector : int = getTimer() - startTime;
 
            startTime = getTimer();
            dataItem = _dataItemLinkedList;
            while ( dataItem )
            {
                dataItem.index = dataItem.index;
                dataItem = dataItem.next;
            }
 
            var durationDataItemLinkedList : int = getTimer() - startTime;
 
            startTime = getTimer( );
            var abstractItem : AbstractItem = _abstractItemLinkedList;
            while ( abstractItem )
            {
                dataItem = abstractItem.data;
                dataItem.index = dataItem.index;
                abstractItem = abstractItem.next;
            }
 
            var durationAbstractItemLinkedList : int = getTimer() - startTime;
 
            startTime = getTimer( );
            abstractItem = _abstractItemLinkedList;
            while ( abstractItem )
            {
                dataItem = DataItem( abstractItem.data );
                dataItem.index = dataItem.index;
                abstractItem = abstractItem.next;
            }
 
            var durationAbstractItemLinkedListWithCast : int = getTimer() - startTime;
 
            startTime = getTimer( );
            abstractItem = _abstractItemLinkedList;
            while ( abstractItem )
            {
                dataItem = abstractItem.data as DataItem;
                dataItem.index = dataItem.index;
                abstractItem = abstractItem.next;
            }
 
            var durationAbstractItemLinkedListWithAs : int = getTimer() - startTime;
 
            trace( "Durations:" );
            trace( "Vector", durationVector );
            trace( "DataItem LinkedList", durationDataItemLinkedList );
            trace( "AbstractItem LinkedList", durationAbstractItemLinkedList );
            trace( "AbstractItemLinkedList Using Cast", durationAbstractItemLinkedListWithCast );
            trace( "AbstractItemLinkedList Using As", durationAbstractItemLinkedListWithAs );
        }
    }
 
}
 
class AbstractItem
{
    public var data : *;
    public var next : AbstractItem;
}
 
class DataItem
{
    public var index : int;
    public var next : DataItem;
}

Results on my MacBook Pro i7:

Durations:
Vector 91
DataItem LinkedList 53
AbstractItem LinkedList 76
AbstractItemLinkedList Using Cast 108
AbstractItemLinkedList Using As 121

Alsways use explicit implemented linked lists!

]]> http://blog.derraab.com/2010/09/22/linked-list-performance-test/feed/ 0 iPhone / iPad ActionScript Guide quotes http://blog.derraab.com/2010/09/17/iphone-ipad-actionscript-guide-quotes/ http://blog.derraab.com/2010/09/17/iphone-ipad-actionscript-guide-quotes/#comments Fri, 17 Sep 2010 22:04:48 +0000 derRaab http://blog.derraab.com/?p=371 Continue reading →]]> As I mentioned here I strongly recommend to read Adobe’s Building ADOBE® AIR® Applications with the Packager for iPhone® guide or Flash Platform for iPhone.

Just some ActionScript facts:

ActionScript APIs unsupported on mobile devices
ActionScript APIs specific to mobile AIR applications
ActionScript APIs of special interest to mobile application developers

]]> http://blog.derraab.com/2010/09/17/iphone-ipad-actionscript-guide-quotes/feed/ 0 Open Source Media Framework 1.0 http://blog.derraab.com/2010/05/28/open-source-media-framework-1-0/ http://blog.derraab.com/2010/05/28/open-source-media-framework-1-0/#comments Fri, 28 May 2010 12:30:19 +0000 derRaab http://blog.derraab.com/?p=289 Adobe recently released OSMF version 1.0! Again just some links:

OSMF Blog – Announcing OSMF 1.0!
Source ZIP
Release Notes PDF
ASDocs ZIP

]]> http://blog.derraab.com/2010/05/28/open-source-media-framework-1-0/feed/ 0 Flash Performance Visualizer http://blog.derraab.com/2010/05/26/flash-performance-visualizer/ http://blog.derraab.com/2010/05/26/flash-performance-visualizer/#comments Wed, 26 May 2010 17:43:48 +0000 derRaab http://blog.derraab.com/?p=283 Continue reading →]]> Mr.doop’s Hi-ReS! Stats is a must have for every ActionScript developer. Seems to be still no. 1!
And I don’t want to search again… So here just the links:

Mr.doop’s blog | Hi-ReS! Stats
Mr.doop’s Stats.as @ GitHub

Update – Most recent version I found:
http://code.google.com/p/mrdoob/source/browse/trunk/libs/net/hires/debug/Stats.as

]]> http://blog.derraab.com/2010/05/26/flash-performance-visualizer/feed/ 0 Undocumented XMLUtil class in Adobe Flash CS5? http://blog.derraab.com/2010/05/18/undocumented-xmlutil-class-in-adobe-flash-cs5/ http://blog.derraab.com/2010/05/18/undocumented-xmlutil-class-in-adobe-flash-cs5/#comments Tue, 18 May 2010 09:39:14 +0000 derRaab http://blog.derraab.com/?p=273 Continue reading →]]> I tried to recompile an older Flash CS 4 project with Flash CS 5 but got this compile time error 1061: Call to a possibly undefined method reuseNodes through a reference with static type Class caused by the usage of one of my utility classes:

This didn’t work

import de.superclass.util.XMLUtil;
...
XMLUtil.someMethod();

This still works

...de.superclass.util.XMLUtil.someMethod();

So there was no error in my class because it’s still usable when I use the full class package but it didn’t work when I just import it with the import statement.

After some research I found an undocumented XMLUtil class which avoids the correct access to my de.superclass.util.XMLUtil class.

This class doesn’t exist in Flash CS 4 but is available in Flash CS 5. Simply create a new FLA in Flash CS 5 an run this code on timeline

trace( describeType( XMLUtil ) );

and you’ll get this result:

<type name="XMLUtil" base="Class" isDynamic="true" isFinal="true" isStatic="true">
  <extendsClass type="Class"/>
  <extendsClass type="Object"/>
  <constant name="kAttrYMin" type="String"/>
  <constant name="kAttrXMax" type="String"/>
  <constant name="kAttrYMax" type="String"/>
  <constant name="kAttrObj0" type="String"/>
  <constant name="kAttrObj1" type="String"/>
  <constant name="kAttrX0" type="String"/>
  <constant name="kAttrY0" type="String"/>
  <constant name="kAttrX1" type="String"/>
  <variable name="kTagGravity" type="String"/>
  <constant name="kAttrY1" type="String"/>
  <variable name="kTagCollideSpace" type="String"/>
  <constant name="kAttrType" type="String"/>
  <variable name="kTagRigidBody" type="String"/>
  <constant name="kAttrPin" type="String"/>
  <variable name="kTagRect" type="String"/>
  <constant name="kAttrSlider" type="String"/>
  <variable name="kTagJoint" type="String"/>
  <constant name="kAttrLength" type="String"/>
  <variable name="kTagSpring" type="String"/>
  <constant name="kAttrStrength" type="String"/>
  <variable name="kTagFrames" type="String"/>
  <constant name="kAttrDamping" type="String"/>
  <variable name="kTagFrame" type="String"/>
  <constant name="kAttrSimSpeed" type="String"/>
  <variable name="kTagFluid" type="String"/>
  <constant name="kAttrAxis" type="String"/>
  <variable name="kTagEmitter" type="String"/>
  <constant name="kAttrAsset" type="String"/>
  <variable name="kTagOrigin" type="String"/>
  <constant name="kAttrSpring" type="String"/>
  <variable name="kTagKeyframes" type="String"/>
  <constant name="kAttrSpringStrength" type="String"/>
  <variable name="kTagKey" type="String"/>
  <constant name="kAttrSpringDamping" type="String"/>
  <variable name="kTagView" type="String"/>
  <variable name="kTagGeom" type="String"/>
  <constant name="kAttrIndex" type="String"/>
  <constant name="kAttrCollideType" type="String"/>
  <constant name="kAttrCellSize" type="String"/>
  <constant name="kAttrSpringValue" type="String"/>
  <constant name="kAttrCollideSpace" type="String"/>
  <constant name="kAttrRowDimen" type="String"/>
  <constant name="kAttrDensity" type="String"/>
  <constant name="kAttrColDimen" type="String"/>
  <constant name="kAttrPosX" type="String"/>
  <constant name="kAttrTimeStep" type="String"/>
  <constant name="kAttrPosY" type="String"/>
  <constant name="kAttrTime" type="String"/>
  <constant name="kAttrAngle" type="String"/>
  <constant name="kAttrColor" type="String"/>
  <constant name="kAttrVelX" type="String"/>
  <constant name="kAttrStrokeColor" type="String"/>
  <constant name="kAttrVelY" type="String"/>
  <constant name="kAttrAlpha" type="String"/>
  <constant name="kAttrVelA" type="String"/>
  <constant name="kAttrFPS" type="String"/>
  <constant name="kAttrCOR" type="String"/>
  <constant name="kAttrSprings" type="String"/>
  <constant name="kAttrCOF" type="String"/>
  <constant name="kAttrLimits" type="String"/>
  <constant name="kAttrFixed" type="String"/>
  <constant name="kAttrMinAngle" type="String"/>
  <constant name="kAttrID" type="String"/>
  <constant name="kAttrDBlend" type="String"/>
  <constant name="kAttrPoseStrength" type="String"/>
  <constant name="kAttrPoseDamping" type="String"/>
  <constant name="kAttrBodyDamping" type="String"/>
  <constant name="kAttrX" type="String"/>
  <constant name="kAttrY" type="String"/>
  <constant name="kAttrXMin" type="String"/>
  <accessor name="prototype" access="readonly" type="*" declaredBy="Class"/>
  <method name="nodeHasAttribute" declaredBy="XMLUtil" returnType="Boolean">
    <parameter index="1" type="XML" optional="false"/>
    <parameter index="2" type="String" optional="false"/>
  </method>
  <method name="getIntAttribute" declaredBy="XMLUtil" returnType="int">
    <parameter index="1" type="XML" optional="false"/>
    <parameter index="2" type="String" optional="false"/>
    <parameter index="3" type="int" optional="true"/>
  </method>
  <method name="getNumberAttribute" declaredBy="XMLUtil" returnType="Number">
    <parameter index="1" type="XML" optional="false"/>
    <parameter index="2" type="String" optional="false"/>
    <parameter index="3" type="Number" optional="true"/>
  </method>
  <method name="getBoolAttribute" declaredBy="XMLUtil" returnType="Boolean">
    <parameter index="1" type="XML" optional="false"/>
    <parameter index="2" type="String" optional="false"/>
    <parameter index="3" type="Boolean" optional="true"/>
  </method>
  <method name="getStringAttribute" declaredBy="XMLUtil" returnType="String">
    <parameter index="1" type="XML" optional="false"/>
    <parameter index="2" type="String" optional="false"/>
    <parameter index="3" type="String" optional="true"/>
  </method>
  <factory type="XMLUtil">
    <extendsClass type="Object"/>
  </factory>
</type>

So I had to rename my class to de.superclass.util.XMLUtils.

You might run into the same problems when using mx.utils.XMLUtil (Flex Framework) or com.adobe.utils.XMLUtil (AS3CoreLib) but I didn’t test it!

UPDATE:
I found XMLUtil classes in
Adobe Flash CS5/Common/Configuration/ActionScript 3.0/libs/ik.swc and
Adobe Flash CS5/Common/Configuration/ActionScript 3.0/libs/PffLib.swc

Removing the $(AppConfig)/ActionScript 3.0/libs directory within the ActionScript export settings avoids the problem. But I have no time to test if this directory is necessary. If you run into problems please leave me a comment!

]]> http://blog.derraab.com/2010/05/18/undocumented-xmlutil-class-in-adobe-flash-cs5/feed/ 3